2 files changed, 53 insertions, 0 deletions
diff --git a/kde-frameworks/kirigami/Manifest b/kde-frameworks/kirigami/Manifest
new file mode 100644
index 00000000000..85f2e6fd910
--- /dev/null
+++ b/kde-frameworks/kirigami/Manifest
@@ -0,0 +1 @@
+DIST kirigami2-5.114.0.tar.xz 382892 BLAKE2B 8cbdac5d4887cf4ffdd1d39359d11e4c5ff7eb7a198ff53ccfe8db16c93f1e063047b1778639b3f284b37d35fffb579c535ff37efa86140e60fcda8d75026b14 SHA512 c666cc62e93b116565c2d47a0381611f824fd6ffcc1c035ca5f86f4be0a438bb8aa0d16775d72fc817ac864fe1b4333d70af646d8e2c21f691118536a384b664
diff --git a/kde-frameworks/kirigami/kirigami-5.114.0.ebuild b/kde-frameworks/kirigami/kirigami-5.114.0.ebuild
new file mode 100644
index 00000000000..75684c65be2
--- /dev/null
+++ b/kde-frameworks/kirigami/kirigami-5.114.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_EXAMPLES="true"
+ECM_QTHELP="false"
+ECM_TEST="true"
+KDE_ORG_TAR_PN="${PN}2"
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org toolchain-funcs
+
+DESCRIPTION="Lightweight user interface framework for mobile and convergent applications"
+HOMEPAGE="https://techbase.kde.org/Kirigami"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="openmp"
+
+# requires package to already be installed
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES=$(usex examples)
+		$(cmake_use_find_package openmp OpenMP)
+	)
+
+	ecm_src_configure
+}