2 files changed, 57 insertions, 0 deletions
diff --git a/kde-frameworks/kidletime/Manifest b/kde-frameworks/kidletime/Manifest
new file mode 100644
index 00000000000..f24d87e8865
--- /dev/null
+++ b/kde-frameworks/kidletime/Manifest
@@ -0,0 +1 @@
+DIST kidletime-5.100.0.tar.xz 30476 BLAKE2B 8be6c7b6c3d249289dbaad120b6153a69bf88d854d35dff84832e76a97491c704df37e0849a0756bd553c0225f4d3c1aaa19baf2f1bb0ad00b9b362f78547c82 SHA512 845c41853f353754189a139ee50d6f92f506ef32b7ba3bae7d021cbfdfa551b5a495c30d5105879dd9dc0dea7f211d706d10c78a47cb4b91218c1286d58b3ef8
diff --git a/kde-frameworks/kidletime/kidletime-5.100.0.ebuild b/kde-frameworks/kidletime/kidletime-5.100.0.ebuild
new file mode 100644
index 00000000000..8e0809da05c
--- /dev/null
+++ b/kde-frameworks/kidletime/kidletime-5.100.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtgui-${QTMIN}:5=[wayland]
+		>=dev-qt/qtwayland-${QTMIN}:5
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtdbus-${QTMIN}:5
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? ( >=dev-libs/plasma-wayland-protocols-1.7.0 )
+"
+BDEPEND="wayland? ( >=dev-qt/qtwaylandscanner-${QTMIN}:5 )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package wayland Qt5WaylandClient)
+		$(cmake_use_find_package X X11)
+		$(cmake_use_find_package X XCB)
+	)
+
+	ecm_src_configure
+}