1 files changed, 82 insertions, 0 deletions
diff --git a/kde-misc/basket/basket-9999.ebuild b/kde-misc/basket/basket-9999.ebuild
new file mode 100644
index 00000000000..0a5c8dfa200
--- /dev/null
+++ b/kde-misc/basket/basket-9999.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.60.0
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Multiple information organizer - a DropDrawers clone"
+HOMEPAGE="https://userbase.kde.org/BasKet https://github.com/basket-notepads/basket"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="https://github.com/${PN}-notepads/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="5"
+IUSE="crypt git"
+
+BDEPEND="git? ( virtual/pkgconfig )"
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/phonon[qt5(+)]
+	x11-libs/libX11
+	crypt? ( app-crypt/gpgme:= )
+	git? ( dev-libs/libgit2:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+PATCHES=(
+	# TODO: upstream
+	"${FILESDIR}/${PN}-2.49b-xdg_mime_install_dir.patch"
+	"${FILESDIR}/${PN}-2.49b-libgit2-0.99-compat.patch" # bug #710832
+)
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use test; then
+		sed -e "/add_subdirectory(tests/s/^/#DONT/" -i src/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Gpgme)
+		$(cmake_use_find_package git Libgit2)
+	)
+	ecm_src_configure
+}