2 files changed, 0 insertions, 78 deletions
diff --git a/kde-plasma/kinfocenter/Manifest b/kde-plasma/kinfocenter/Manifest
index 32e701a850a..c5bffaee3ec 100644
--- a/kde-plasma/kinfocenter/Manifest
+++ b/kde-plasma/kinfocenter/Manifest
@@ -1,2 +1 @@
 DIST glogo-small.png 24583 BLAKE2B 0af2ceae708e56f217120e5d8b880fb71401e3761ab26c4af5e74c0622368aa4e34b05160fae15fbfbbc832077810ab5c1e424826632748299fd22997cbe665c SHA512 648be463ec3812a2edcdab54d7a230bf2bd7e6895f4ffe72321d8fca28a5e1e0980f6e3b9a32f369c8369943ceb802a65a94b9dad820dcf2c81d4581d814cb48
-DIST kinfocenter-5.92.0.tar.xz 830248 BLAKE2B 6ea9e432acda4680ac1e53d3d31d8cbe6df3169873a970740c9d70e3740e49aadaa4fa0a9e71ccaf531d1089490246d4210704ecbef07524d5a3342c1b893c1e SHA512 77d95f160731732901b0cd5a612c600e9e65cf95fbf52275a55f574e20b53138292b6eb2cde81ddd33cc51f0c048945a4b8b15116b8bc3d6bed720145301e2e8
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.92.0.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.92.0.ebuild
deleted file mode 100644
index a15d7301ef1..00000000000
--- a/kde-plasma/kinfocenter/kinfocenter-5.92.0.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-KFMIN=5.248.0
-PVCUT=$(ver_cut 1-3)
-QTMIN=6.6.0
-inherit ecm plasma.kde.org optfeature
-
-DESCRIPTION="Utility providing information about the computer hardware"
-HOMEPAGE="https://userbase.kde.org/KInfoCenter"
-SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64"
-IUSE="gles2-only usb"
-
-DEPEND="
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gles2-only=,gui,widgets]
-	>=dev-qt/qtdeclarative-${QTMIN}:6
-	>=kde-frameworks/kauth-${KFMIN}:6
-	>=kde-frameworks/kcmutils-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/kservice-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/solid-${KFMIN}:6
-	gles2-only? ( media-libs/mesa[gles2] )
-	usb? ( virtual/libusb:1 )
-"
-RDEPEND="${DEPEND}
-	dev-qt/qdbus:*
-	>=kde-frameworks/kirigami-${KFMIN}:6
-	>=kde-plasma/kde-cli-tools-${PVCUT}:*
-	>=kde-plasma/systemsettings-${PVCUT}:6
-"
-BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package usb USB1)
-		-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # missing
-	)
-
-	ecm_src_configure
-}
-
-src_install() {
-	ecm_src_install
-
-	# TODO: Make this fully obsolete by /etc/os-release
-	insinto /etc/xdg
-	doins "${FILESDIR}"/kcm-about-distrorc
-
-	insinto /usr/share/${PN}
-	doins "${DISTDIR}"/glogo-small.png
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "NFS information module" net-fs/nfs-utils
-		optfeature "Samba status information module" net-fs/samba
-		optfeature "Vulkan graphics API information module" dev-util/vulkan-tools
-		optfeature "advanced CPU information module" sys-apps/util-linux
-	fi
-	optfeature "Wayland information module" app-misc/wayland-utils
-	optfeature "Firmware security module" "app-text/aha sys-apps/fwupd"
-	optfeature "OpenGL information module" x11-apps/mesa-progs
-	optfeature "PCI devices information module" sys-apps/pciutils
-	optfeature "X Server information module" x11-apps/xdpyinfo
-	ecm_pkg_postinst
-}