From bf6e58f9ff14d94f3f50b6425d7ed0aafe17952f Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 4 Nov 2025 20:06:36 +0100
Subject: app-cdr/dolphin-plugins-mountiso: 25.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 app-cdr/dolphin-plugins-mountiso/Manifest          |  1 +
 .../dolphin-plugins-mountiso-25.08.3.ebuild        | 58 ++++++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 app-cdr/dolphin-plugins-mountiso/Manifest
 create mode 100644 app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-25.08.3.ebuild

diff --git a/app-cdr/dolphin-plugins-mountiso/Manifest b/app-cdr/dolphin-plugins-mountiso/Manifest
new file mode 100644
index 00000000000..aa1293eb5ce
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-25.08.3.tar.xz 336856 BLAKE2B 7714809fde0c00ba52c002c3ed6a12a2006a2a3cf980e211ff5c736ef2138e50acddc03f70ffc70030313cbaabf259de826129c0766354a389c27655cb164b9c SHA512 df887b3be57da1344f5311093ba13251c4af554f4f3d93b3e44c0835da21ac8cec0fccaaee7e8b8e9162e56b1396bcbbded2bc5f02955b30ba01203fff0a279a
diff --git a/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-25.08.3.ebuild b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-25.08.3.ebuild
new file mode 100644
index 00000000000..ee110d45727
--- /dev/null
+++ b/app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-25.08.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=6.16.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.9.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# qtconcurrent only required by git
+	ecm_punt_qt_module Concurrent
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_makefileactions=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
-- 
cgit v1.2.3