From ef1ac28591e18c9620612e0833d85db29549695c Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 13 Dec 2023 00:25:19 +0100
Subject: kde-apps/kio-extras-kf5: New package for KF5-based KDE apps compat

Dependency changes by upstream commits:
1a98236939072fd3143262e74c528baf0e521d67
f220e0ebf670e64f3e7dc4d8a75c3b5dd00bfe2c
1571e95afd0c8e38de5c45e0121d5d9a36d30957

See also:
https://community.kde.org/KDE_Gear/24.02_Release_notes#Tarballs_which_are_needed_as_Qt_5_and_Qt_6_Builds

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/kio-extras-kf5/kio-extras-kf5-9999.ebuild | 96 ++++++++++++++++++++++
 kde-apps/kio-extras-kf5/metadata.xml               | 23 ++++++
 2 files changed, 119 insertions(+)
 create mode 100644 kde-apps/kio-extras-kf5/kio-extras-kf5-9999.ebuild
 create mode 100644 kde-apps/kio-extras-kf5/metadata.xml

diff --git a/kde-apps/kio-extras-kf5/kio-extras-kf5-9999.ebuild b/kde-apps/kio-extras-kf5/kio-extras-kf5-9999.ebuild
new file mode 100644
index 00000000000..3001cce90ef
--- /dev/null
+++ b/kde-apps/kio-extras-kf5/kio-extras-kf5-9999.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KDE_ORG_NAME="kio-extras"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
+HOMEPAGE="https://invent.kde.org/network/kio-extras"
+EGIT_BRANCH="kf5"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS=""
+IUSE="ios kf6compat +man mtp nfs openexr phonon samba +sftp taglib X"
+
+# requires running Plasma environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	kde-apps/libkexiv2:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdnssd-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	>=kde-plasma/plasma-activities-${KFMIN}:5
+	>=kde-plasma/plasma-activities-stats-${KFMIN}:5
+	ios? (
+		app-pda/libimobiledevice:=
+		app-pda/libplist:=
+	)
+	mtp? ( >=media-libs/libmtp-1.1.16:= )
+	nfs? ( net-libs/libtirpc:= )
+	openexr? ( media-libs/openexr:= )
+	phonon? ( >=media-libs/phonon-4.11.0[qt5(+)] )
+	samba? ( net-fs/samba[client] )
+	sftp? ( net-libs/libssh:=[sftp] )
+	taglib? ( >=media-libs/taglib-1.11.1 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+	)
+"
+RDEPEND="${DEPEND}
+	!kde-apps/kio-extras:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	kf6compat? ( kde-apps/kio-extras:6 )
+"
+BDEPEND="man? ( dev-util/gperf )"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package ios IMobileDevice)
+		$(cmake_use_find_package ios PList)
+		$(cmake_use_find_package man Gperf)
+		$(cmake_use_find_package mtp Libmtp)
+		$(cmake_use_find_package nfs TIRPC)
+		-DKF6_COMPAT_BUILD=$(usex kf6compat)
+		$(cmake_use_find_package openexr OpenEXR)
+		$(cmake_use_find_package phonon Phonon4Qt5)
+		$(cmake_use_find_package samba Samba)
+		$(cmake_use_find_package sftp libssh)
+		$(cmake_use_find_package taglib Taglib)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	use samba && mycmakeargs+=(
+		# do not attempt to find now Qt6-based system version
+		-DCMAKE_DISABLE_FIND_PACKAGE_KDSoapWSDiscoveryClient=ON
+	)
+
+	ecm_src_configure
+}
diff --git a/kde-apps/kio-extras-kf5/metadata.xml b/kde-apps/kio-extras-kf5/metadata.xml
new file mode 100644
index 00000000000..72853d9bad5
--- /dev/null
+++ b/kde-apps/kio-extras-kf5/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://bugs.kde.org/</bugs-to>
+		<remote-id type="cpe">cpe:/a:kde:kio-extras</remote-id>
+		<remote-id type="kde-invent">network/kio-extras</remote-id>
+	</upstream>
+	<use>
+		<flag name="ios">Enable AFC (Apple File Conduit) KIO worker for iOS devices support</flag>
+		<flag name="kf6compat">Disable components colliding with KF6, depend on KF6 components instead</flag>
+		<flag name="man">Enable manpages KIO worker</flag>
+		<flag name="nfs">Enable NFS support using <pkg>net-libs/libtirpc</pkg></flag>
+		<flag name="phonon">Enable file audio preview plugin using <pkg>media-libs/phonon</pkg></flag>
+		<flag name="sftp">Enable SFTP protocol support using <pkg>net-libs/libssh</pkg></flag>
+		<flag name="taglib">Enable audio thumbnails via <pkg>media-libs/taglib</pkg></flag>
+		<flag name="X">Enable support for XCursor thumbnails via <pkg>x11-libs/libX11</pkg></flag>
+	</use>
+</pkgmetadata>
-- 
cgit v1.2.3