From 32fbebd374ef535cd93cc41f6df23ac8d4f9948b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 9 Sep 2025 16:32:14 +0200
Subject: dev-libs/kopeninghours: 25.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-libs/kopeninghours/Manifest                    |  1 +
 .../kopeninghours/kopeninghours-25.08.1.ebuild     | 57 ++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 dev-libs/kopeninghours/Manifest
 create mode 100644 dev-libs/kopeninghours/kopeninghours-25.08.1.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/kopeninghours/Manifest b/dev-libs/kopeninghours/Manifest
new file mode 100644
index 00000000000..14d4414b2e0
--- /dev/null
+++ b/dev-libs/kopeninghours/Manifest
@@ -0,0 +1 @@
+DIST kopeninghours-25.08.1.tar.xz 75972 BLAKE2B 8f9d91e41b40d511ca9c5008ed2fccdf988a3b7b758502673b763323ce87e1d5b5fef496878246dbd4b8823e15a47d30cc0e1ff19b809eca198c380e5f7a62ad SHA512 5f785ce37797fd350b09a288d7bd11ac70203e00e3772ac1caa68bdd97e503ea2033e8ab719068550b35fa246cabd163799475d4e113cabaebe2c9f3abfd2001
diff --git a/dev-libs/kopeninghours/kopeninghours-25.08.1.ebuild b/dev-libs/kopeninghours/kopeninghours-25.08.1.ebuild
new file mode 100644
index 00000000000..16efc26683e
--- /dev/null
+++ b/dev-libs/kopeninghours/kopeninghours-25.08.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="true"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.16.0
+QTMIN=6.9.1
+PYTHON_COMPAT=( python3_{10..13} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Library for parsing and evaluating OSM opening hours expressions"
+HOMEPAGE="https://api.kde.org/kopeninghours/html/index.html
+https://invent.kde.org/libraries/kopeninghours"
+
+LICENSE="LGPL-2+"
+SLOT="6/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm64"
+IUSE="python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/kpublictransport-${PVCUT}:6=
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kholidays-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	sys-libs/zlib
+	python? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	app-alternatives/lex
+	app-alternatives/yacc
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_LIBRARY=$(python_get_library_path)
+		-DPython_INCLUDE_DIR=$(python_get_includedir)
+		$(cmake_use_find_package python Boost)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	python_optimize
+}
-- 
cgit v1.2.3