From eff7faa8d68013fec67b933423f726fb5dc33cdd Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Mon, 11 Nov 2024 19:42:14 +0100
Subject: dev-libs/kopeninghours: Add 24.12 stable branch

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../kopeninghours-24.12.49.9999.ebuild             | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 dev-libs/kopeninghours/kopeninghours-24.12.49.9999.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/kopeninghours/kopeninghours-24.12.49.9999.ebuild b/dev-libs/kopeninghours/kopeninghours-24.12.49.9999.ebuild
new file mode 100644
index 00000000000..43312e1f234
--- /dev/null
+++ b/dev-libs/kopeninghours/kopeninghours-24.12.49.9999.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="true"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.5.0
+QTMIN=6.7.2
+PYTHON_COMPAT=( python3_{10..12} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Library for parsing and evaluating OSM opening hours expressions"
+HOMEPAGE="https://api.kde.org/kopeninghours/html/index.html
+https://invent.kde.org/libraries/kopeninghours"
+
+LICENSE="LGPL-2+"
+SLOT="6"
+KEYWORDS=""
+IUSE="python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/kpublictransport-${PVCUT}:6
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kholidays-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	sys-libs/zlib
+	python? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	app-alternatives/lex
+	app-alternatives/yacc
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-22.04.0-boostpython.patch )
+
+pkg_setup() {
+	ecm_pkg_setup
+	python_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package python Boost)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	python_optimize
+}
-- 
cgit v1.2.3