From 8ff6a00d445a7effbfa9d964534741e0157bb02b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 6 Nov 2025 17:37:37 +0100
Subject: kde-apps/kio-extras: drop 25.08.49.9999

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../kio-extras/kio-extras-25.08.49.9999.ebuild     | 109 ---------------------
 kde-apps/kio-extras/metadata.xml                   |   1 -
 2 files changed, 110 deletions(-)
 delete mode 100644 kde-apps/kio-extras/kio-extras-25.08.49.9999.ebuild

(limited to 'kde-apps/kio-extras')

diff --git a/kde-apps/kio-extras/kio-extras-25.08.49.9999.ebuild b/kde-apps/kio-extras/kio-extras-25.08.49.9999.ebuild
deleted file mode 100644
index 6e3fd248122..00000000000
--- a/kde-apps/kio-extras/kio-extras-25.08.49.9999.ebuild
+++ /dev/null
@@ -1,109 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KFMIN=6.16.0
-QTMIN=6.9.1
-inherit ecm gear.kde.org optfeature xdg
-
-DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
-HOMEPAGE="https://invent.kde.org/network/kio-extras"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS=""
-IUSE="activities ios +man mtp nfs +libproxy openexr phonon samba +sftp taglib X"
-
-# requires running Plasma environment
-RESTRICT="test"
-
-DEPEND="
-	dev-libs/qcoro
-	>=dev-qt/qt5compat-${QTMIN}:6
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
-	>=dev-qt/qtsvg-${QTMIN}:6
-	kde-apps/libkexiv2:6
-	>=kde-frameworks/karchive-${KFMIN}:6
-	>=kde-frameworks/kcmutils-${KFMIN}:6
-	>=kde-frameworks/kcodecs-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kdbusaddons-${KFMIN}:6
-	>=kde-frameworks/kdnssd-${KFMIN}:6
-	>=kde-frameworks/kguiaddons-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/kservice-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	>=kde-frameworks/solid-${KFMIN}:6
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
-	activities? (
-		>=dev-qt/qtbase-${QTMIN}:6[sql]
-		kde-plasma/plasma-activities:6=
-		kde-plasma/plasma-activities-stats:6
-	)
-	ios? (
-		app-pda/libimobiledevice:=
-		app-pda/libplist:=
-	)
-	libproxy? (
-		>=kde-frameworks/knotifications-${KFMIN}:6
-		net-libs/libproxy
-	)
-	mtp? ( >=media-libs/libmtp-1.1.16:= )
-	nfs? ( net-libs/libtirpc:= )
-	openexr? ( media-libs/openexr:= )
-	phonon? ( >=media-libs/phonon-4.12.0[qt6(+)] )
-	samba? (
-		net-fs/samba[client]
-		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
-		>=net-libs/kdsoap-ws-discovery-client-0.3.0
-	)
-	sftp? ( net-libs/libssh:=[sftp] )
-	taglib? ( >=media-libs/taglib-1.11.1:= )
-	X? (
-		x11-libs/libX11
-		x11-libs/libXcursor
-	)
-"
-RDEPEND="${DEPEND}
-	!kde-apps/kio-extras:5[-kf6compat(-)]
-	!kde-apps/kio-extras-kf5:5
-	!<kde-frameworks/kio-5.116.0-r2:5
-	!kde-frameworks/kio-trash-desktop-file:5
-	>=kde-frameworks/kded-${KFMIN}:6
-"
-BDEPEND="man? ( dev-util/gperf )"
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_ACTIVITIES=$(usex activities)
-		$(cmake_use_find_package ios IMobileDevice)
-		$(cmake_use_find_package ios PList)
-		-DWITH_LIBPROXY=$(usex libproxy)
-		$(cmake_use_find_package man Gperf)
-		$(cmake_use_find_package mtp Libmtp)
-		$(cmake_use_find_package nfs TIRPC)
-		$(cmake_use_find_package openexr OpenEXR)
-		$(cmake_use_find_package phonon Phonon4Qt6)
-		$(cmake_use_find_package samba Samba)
-		$(cmake_use_find_package sftp libssh)
-		$(cmake_use_find_package taglib Taglib)
-		-DWITHOUT_X11=$(usex !X)
-	)
-	ecm_src_configure
-}
-
-pkg_postinst() {
-	optfeature "alternative filename search backend" sys-apps/ripgrep
-	use samba && xdg_pkg_postinst
-}
-
-pkg_postrm() {
-	use samba && xdg_pkg_postrm
-}
diff --git a/kde-apps/kio-extras/metadata.xml b/kde-apps/kio-extras/metadata.xml
index 14a96cf4117..fd86c7feccd 100644
--- a/kde-apps/kio-extras/metadata.xml
+++ b/kde-apps/kio-extras/metadata.xml
@@ -16,7 +16,6 @@
 		<flag name="libproxy">Enable support for WPAD problem detection via <pkg>net-libs/libproxy</pkg></flag>
 		<flag name="man">Enable manpages KIO worker</flag>
 		<flag name="nfs">Enable NFS support using <pkg>net-libs/libtirpc</pkg></flag>
-		<flag name="phonon">Enable file audio preview plugin using <pkg>media-libs/phonon</pkg></flag>
 		<flag name="sftp">Enable SFTP protocol support using <pkg>net-libs/libssh</pkg></flag>
 		<flag name="taglib">Enable audio thumbnails via <pkg>media-libs/taglib</pkg></flag>
 		<flag name="X">Enable support for XCursor thumbnails via <pkg>x11-libs/libX11</pkg></flag>
-- 
cgit v1.2.3