From 7733c13e3858a8c39e99ab8d901b3a14d59d5e7d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 16 Apr 2021 21:02:26 +0200
Subject: kde-apps/dolphin-plugins-mercurial: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/dolphin-plugins-mercurial/Manifest        |  1 +
 .../dolphin-plugins-mercurial-21.04.0.ebuild       | 69 ++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 kde-apps/dolphin-plugins-mercurial/Manifest
 create mode 100644 kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.04.0.ebuild

(limited to 'kde-apps')

diff --git a/kde-apps/dolphin-plugins-mercurial/Manifest b/kde-apps/dolphin-plugins-mercurial/Manifest
new file mode 100644
index 00000000000..386a0581164
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/Manifest
@@ -0,0 +1 @@
+DIST dolphin-plugins-21.04.0.tar.xz 242608 BLAKE2B c12366f9a0d661e79b968ce375e2ea46dd8d90f322691755dc238d4dd08d07f6527711aa117fead2a3714d7f97c508e53c5ecd87a69c23c397e44033669fe5b1 SHA512 9f093133eba93615392a117f8184177f06bb117d4a3ad4691025ef26e4d83e251f966c157ae107f52447c78bf600ab586a175f57a02f78fec8e620aa5462138d
diff --git a/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.04.0.ebuild b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.04.0.ebuild
new file mode 100644
index 00000000000..89dca504705
--- /dev/null
+++ b/kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-21.04.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/en/dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	dev-vcs/mercurial
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_bogus_dep Qt5 Network
+	ecm_punt_bogus_dep KF5 XmlGui
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}
-- 
cgit v1.2.3