From f3d9f4ab12a3606496e4e6156135a895eef5a47c Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Sun, 27 Apr 2014 04:08:13 +1000
Subject: Rename kde-base/*-9999:4 to 4.9999.

This lets us handle the case where a package has both KDE 4 and 5 versions
served out of master of different repositories.
---
 kde-base/cantor/cantor-4.9999.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 kde-base/cantor/cantor-4.9999.ebuild

(limited to 'kde-base/cantor/cantor-4.9999.ebuild')

diff --git a/kde-base/cantor/cantor-4.9999.ebuild b/kde-base/cantor/cantor-4.9999.ebuild
new file mode 100644
index 00000000000..6e4a22f6042
--- /dev/null
+++ b/kde-base/cantor/cantor-4.9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+PYTHON_COMPAT=( python2_7 )
+inherit kde4-base python-single-r1
+
+DESCRIPTION="KDE4 interface for doing mathematics and scientific computing"
+HOMEPAGE="http://www.kde.org/applications/education/cantor http://edu.kde.org/cantor"
+KEYWORDS=""
+IUSE="analitza debug postscript python qalculate +R"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
+RDEPEND="
+	analitza? ( $(add_kdebase_dep analitza) )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate
+	)
+	postscript? ( app-text/libspectre )
+	python? ( ${PYTHON_DEPS} )
+	R? ( dev-lang/R )
+	dev-qt/qtxmlpatterns:4
+"
+DEPEND="${RDEPEND}
+	>=dev-cpp/eigen-2.0.3:2
+"
+
+RESTRICT="test"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with analitza)
+		$(cmake-utils_use_with postscript LibSpectre)
+		$(cmake-utils_use_with python PythonLibs)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with R)
+	)
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if ! use analitza && ! use python && ! use qalculate && ! use R; then
+		echo
+		ewarn "You have decided to build ${PN} with no backend."
+		ewarn "To have this application functional, please do one of below:"
+		ewarn "    # emerge -va1 '='${CATEGORY}/${P} with 'analitza', 'python', 'qalculate' or 'R' USE flag enabled"
+		ewarn "    # emerge -vaDu sci-mathematics/maxima"
+		echo
+	fi
+}
-- 
cgit v1.2.3