From 9e3798db11b51fc485c214d5213a5a84c88246b3 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 5 Oct 2025 23:38:12 +0200
Subject: kde-frameworks/kidletime: 6.19.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-frameworks/kidletime/Manifest                |  1 +
 kde-frameworks/kidletime/kidletime-6.19.0.ebuild | 58 ++++++++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 kde-frameworks/kidletime/Manifest
 create mode 100644 kde-frameworks/kidletime/kidletime-6.19.0.ebuild

(limited to 'kde-frameworks')

diff --git a/kde-frameworks/kidletime/Manifest b/kde-frameworks/kidletime/Manifest
new file mode 100644
index 00000000000..4d600a3bd6a
--- /dev/null
+++ b/kde-frameworks/kidletime/Manifest
@@ -0,0 +1 @@
+DIST kidletime-6.19.0.tar.xz 30816 BLAKE2B 82af2045e9c6fbdd4ccdc81284b8aa46fd692424ca36373a6475e244b54c60aaf0a88dd39e145d95ad18282ad4ef5d0d33997487b927d0bccb69629f5a48e4ce SHA512 33bb975a7d648bf6925dc384692f5816d937a9513c1219142bb4a76ba84a96b287a921e41e3dcb98d16671a76db6e009a78f9786855cd8b0bc44a130bc9c9018
diff --git a/kde-frameworks/kidletime/kidletime-6.19.0.ebuild b/kde-frameworks/kidletime/kidletime-6.19.0.ebuild
new file mode 100644
index 00000000000..a027b39ea50
--- /dev/null
+++ b/kde-frameworks/kidletime/kidletime-6.19.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtbase-${QTMIN}:6=[wayland]
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus]
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		>=dev-libs/plasma-wayland-protocols-1.11.1
+		>=dev-libs/wayland-protocols-1.27:0
+	)
+"
+RDEPEND+=" wayland? ( || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 ) )"
+BDEPEND="wayland? ( >=dev-qt/qtbase-${QTMIN}:6[wayland] )"
+BDEPEND+=" wayland? ( || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 ) )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_WAYLAND=$(usex wayland)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}
-- 
cgit v1.2.3