From ff309b4c656260142f11c8041495afa018688154 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 4 Oct 2024 23:35:56 +0200
Subject: kde-frameworks/kfilemetadata: 6.7.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-frameworks/kfilemetadata/Manifest              |  1 +
 .../kfilemetadata/kfilemetadata-6.7.0.ebuild       | 66 ++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 kde-frameworks/kfilemetadata/Manifest
 create mode 100644 kde-frameworks/kfilemetadata/kfilemetadata-6.7.0.ebuild

(limited to 'kde-frameworks')

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
new file mode 100644
index 00000000000..87d216b6f3b
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -0,0 +1 @@
+DIST kfilemetadata-6.7.0.tar.xz 594612 BLAKE2B a6a022d8fe3424759cf1522d8eb74336a106639a4a65e86dab637753fb0d6eeecfc3197bd831725f3105ba1f7c6750c42b3442588a180ea119c4f47bf71bd527 SHA512 87262420e8358bb7a932ca9f0cfa99574c2beeba3c6277b0e6ff85bd0fd82366445b1c1224735fbf736965127658a8800522378bcc112a90270029f120c9198a
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-6.7.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-6.7.0.ebuild
new file mode 100644
index 00000000000..5c5b4bd42ba
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-6.7.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=6.6.2
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,xml]
+	=kde-frameworks/karchive-${PVCUT}*:6
+	=kde-frameworks/kcodecs-${PVCUT}*:6
+	=kde-frameworks/kcoreaddons-${PVCUT}*:6
+	=kde-frameworks/ki18n-${PVCUT}*:6
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:6 )
+	pdf? ( app-text/poppler[qt6(-)] )
+	taglib? ( media-libs/taglib:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+CMAKE_SKIP_TESTS=(
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	usermetadatawritertest
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket6)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+	ecm_pkg_postinst
+}
-- 
cgit v1.2.3