From a0d860e3cf2b352f494fbbfda1f5b5732b439b4c Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 5 Jul 2025 14:24:51 +0200
Subject: net-libs/libktorrent: drop 25.04.49.9999

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../libktorrent/libktorrent-25.04.49.9999.ebuild   | 65 ----------------------
 1 file changed, 65 deletions(-)
 delete mode 100644 net-libs/libktorrent/libktorrent-25.04.49.9999.ebuild

(limited to 'net-libs')

diff --git a/net-libs/libktorrent/libktorrent-25.04.49.9999.ebuild b/net-libs/libktorrent/libktorrent-25.04.49.9999.ebuild
deleted file mode 100644
index 6b0f2ed9c37..00000000000
--- a/net-libs/libktorrent/libktorrent-25.04.49.9999.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_TEST="forceoptional"
-KDE_ORG_CATEGORY="network"
-KFMIN=6.13.0
-QTMIN=6.7.2
-inherit ecm gear.kde.org
-
-DESCRIPTION="BitTorrent library based on KDE Frameworks"
-HOMEPAGE="https://apps.kde.org/ktorrent/ https://userbase.kde.org/KTorrent"
-
-LICENSE="GPL-2+"
-SLOT="6"
-KEYWORDS=""
-IUSE="xfs"
-
-COMMON_DEPEND="
-	>=app-crypt/qca-2.3.7:2[qt6(+)]
-	>=dev-libs/gmp-6.0.0a:0=
-	dev-libs/libgcrypt:0=
-	>=dev-qt/qtbase-${QTMIN}:6[network,xml]
-	>=kde-frameworks/karchive-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/solid-${KFMIN}:6
-	xfs? ( sys-fs/xfsprogs )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/boost-1.71
-"
-RDEPEND="${COMMON_DEPEND}
-	!dev-libs/botan[gmp(-)]
-"
-BDEPEND="sys-devel/gettext"
-
-src_prepare() {
-	ecm_src_prepare
-
-	# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
-	sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
-		CMakeLists.txt || die
-	sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
-		KTorrent6Config.cmake.in || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DWITH_XFS=$(usex xfs)
-	)
-	ecm_src_configure
-}
-
-src_test() {
-	# failing network tests
-	local myctestargs=(
-		-E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
-	)
-	ecm_src_test
-}
-- 
cgit v1.2.3