From ac12bc48e2ad23d7cb9ddc5e4ce287e1efc94585 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 11 Oct 2022 18:17:28 +0200
Subject: sys-auth/polkit-qt: Add IUSE qt6

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 sys-auth/polkit-qt/polkit-qt-9999.ebuild | 40 ++++++++++++++++++++++++--------
 1 file changed, 30 insertions(+), 10 deletions(-)

(limited to 'sys-auth/polkit-qt')

diff --git a/sys-auth/polkit-qt/polkit-qt-9999.ebuild b/sys-auth/polkit-qt/polkit-qt-9999.ebuild
index a6777dd47d8..76b8d6b2208 100644
--- a/sys-auth/polkit-qt/polkit-qt-9999.ebuild
+++ b/sys-auth/polkit-qt/polkit-qt-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 KDE_ORG_CATEGORY="libraries"
 KDE_ORG_NAME="polkit-qt-1"
-inherit cmake kde.org
+inherit cmake kde.org multibuild
 
 DESCRIPTION="Qt wrapper around polkit-1 client libraries"
 HOMEPAGE="https://api.kde.org/polkit-qt-1/html/"
@@ -17,24 +17,44 @@ fi
 
 LICENSE="LGPL-2"
 SLOT="0"
-IUSE=""
+IUSE="+qt5 qt6"
+REQUIRED_USE="|| ( qt5 qt6 )"
 
 RDEPEND="
 	dev-libs/glib:2
-	dev-qt/qtcore:5
-	dev-qt/qtdbus:5
-	dev-qt/qtgui:5
-	dev-qt/qtwidgets:5
 	>=sys-auth/polkit-0.103
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[dbus,gui,widgets] )
 "
 DEPEND="${RDEPEND}"
 BDEPEND="virtual/pkgconfig"
 
 DOCS=( AUTHORS README README.porting TODO )
 
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
 src_configure() {
-	local mycmakeargs=(
-		-DBUILD_EXAMPLES=OFF
-	)
-	cmake_src_configure
+	myconfigure() {
+		local mycmakeargs=(
+			-DBUILD_EXAMPLES=OFF
+			-DQT_MAJOR_VERSION=${MULTIBUILD_VARIANT/qt/}
+		)
+		cmake_src_configure
+	}
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
 }
-- 
cgit v1.2.3