# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/eigen-2.0.2.ebuild,v 1.1 2009/06/04 10:26:04 scarabeus Exp $

EAPI="2"
inherit cmake-utils subversion

DESCRIPTION="Lightweight C++ template library for vector and matrix math, a.k.a. linear algebra"
HOMEPAGE="http://eigen.tuxfamily.org/"
#SRC_URI="http://download.tuxfamily.org/${PN}/${P/_/-}.tar.bz2"
ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/kdesupport/eigen2"


LICENSE="GPL-3"
SLOT="2"
KEYWORDS=""
IUSE="debug demos doc"

DEPEND="
	demos? (
		x11-libs/qt-gui:4
		x11-libs/qt-opengl:4
	)
"
RDEPEND="${DEPEND}
	!dev-cpp/eigen:0
"

src_configure() {
	# benchmarks (BTL) brings up damn load of external deps including fortran
	# compiler
	# library hangs up complete compilation proccess, test later
	mycmakeargs="
		-DEIGEN_BUILD_LIB=OFF
		-DEIGEN_BUILD_BTL=OFF
		$(cmake-utils_use demos EIGEN_BUILD_DEMOS)
	"
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc; then
		cd ${CMAKE_BUILD_DIR}
		emake doc || die "building documentation failed"
	fi
}

src_test() {
	mycmakeargs="${mycmakeargs}
		-DEIGEN_BUILD_TESTS=ON
	"
	cmake-utils_src_configure
	cmake-utils_src_compile
	cmake-utils_src_test
}