dev-python/sigstore: Bump to 3.6.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/sigstore/Manifest b/dev-python/sigstore/Manifest
index fe3c2ddde363..700a98e13bc1 100644
--- a/dev-python/sigstore/Manifest
+++ b/dev-python/sigstore/Manifest
@@ -1 +1,2 @@
 DIST sigstore-python-3.6.4.gh.tar.gz 281124 BLAKE2B 563b7cd22e6967c0f5ae74d15b79eca1efb3137966a986d6b7f87fc336f487820ea7a64924e68cc8bedcc473f4722f7f72cf55ee8c3f57d1867e6874b76cffd3 SHA512 1b6d942a68ec8b468541f247f01f0895012a2c0390b44532a369491c1d06a9995b42c9baf3411325e801a64d914de7e7581a59662c1b0e2b6c0e49742c256740
+DIST sigstore-python-3.6.5.gh.tar.gz 281176 BLAKE2B 23d4ccffaa2e779fdb65406f452d0c559a2c0699560d996f3b71d326d38da38bc6a264c3d4195b866d9764289a986de7f732afc64f33995f98557e759baf0c79 SHA512 a4fd2cfe1619db363b33ea03e940ae6d3b97bb838501d704926cf32b63f7c2ce75ace9915ec466ab4a9714c9a2b45578aa3006b9c19ca022c588d50bb53ae5bb
diff --git a/dev-python/sigstore/sigstore-3.6.5.ebuild b/dev-python/sigstore/sigstore-3.6.5.ebuild
new file mode 100644
index 000000000000..cd0c4cc24d57
--- /dev/null
+++ b/dev-python/sigstore/sigstore-3.6.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=sigstore-python-${PV}
+DESCRIPTION="A tool for signing Python package distributions"
+HOMEPAGE="
+	https://github.com/sigstore/sigstore-python/
+	https://pypi.org/project/sigstore/
+"
+# no tests in sdist, as of 3.3.0
+SRC_URI="
+	https://github.com/sigstore/sigstore-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cryptography-42[${PYTHON_USEDEP}]
+	>=dev-python/id-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.6[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.1[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	~dev-python/rfc3161-client-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc8785-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/rich-13[${PYTHON_USEDEP}]
+	~dev-python/sigstore-protobuf-specs-0.3.2[${PYTHON_USEDEP}]
+	~dev-python/sigstore-rekor-types-0.0.18[${PYTHON_USEDEP}]
+	>=dev-python/tuf-6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -r -i -e 's:~=:>=:' -e 's:, ?< ?[0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	epytest test/unit --skip-online
+}