www-plugins/lightspark: Bump to 0.9.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/www-plugins/lightspark/Manifest b/www-plugins/lightspark/Manifest
index 3bb917c18c1e..127239198886 100644
--- a/www-plugins/lightspark/Manifest
+++ b/www-plugins/lightspark/Manifest
@@ -1 +1,2 @@
 DIST lightspark-0.8.7.tar.gz 5440706 BLAKE2B 53486183672c35a8b8040177ebc738e588c3ea39a316d2dd10fc4868393b0befea5ac9f411cdb87aad608f02df2f04e07b4a7f8a0635c0f6e0dee465469709f4 SHA512 a0207629238054d669710fcb4d6b1904624d4ed8fb19cf822447e55107d6c3596f6e9fb425c14968365a1c8224b7c3a899008428fd69c9714a03a74230e64f2f
+DIST lightspark-0.9.0.tar.gz 96346962 BLAKE2B 21133fcaf6f9b6b4cbd6842c68bb4d25b63a8654fe7d9c200600dd762bf4bc631164110ea25b4d8808a1d90b46bc1b2ab99e1df5a4d07202ecec422391da3737 SHA512 e2570a1d603685ae0d2945049b4db07a80e5b782d601f94f09a31b12f9e2f4c359a2596be7238f1b4ea9a204778c4bb7f994f8c7cd575619178f9e83393ad0da
diff --git a/www-plugins/lightspark/lightspark-0.9.0.ebuild b/www-plugins/lightspark/lightspark-0.9.0.ebuild
new file mode 100644
index 000000000000..6b78e5a21e06
--- /dev/null
+++ b/www-plugins/lightspark/lightspark-0.9.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="High performance flash player"
+HOMEPAGE="https://lightspark.github.io/"
+SRC_URI="
+	https://github.com/lightspark/lightspark/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S=${WORKDIR}/${P/_rc*/}
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles2-only nsplugin ppapi profile rtmp"
+
+# Note: no LLVM since it's broken upstream
+RDEPEND="
+	app-arch/xz-utils:=
+	dev-libs/glib
+	dev-libs/libpcre:=[cxx]
+	media-fonts/liberation-fonts
+	media-libs/freetype:=
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	sys-libs/zlib:=
+	x11-libs/cairo
+	x11-libs/libX11
+	x11-libs/pango
+	curl? ( net-misc/curl:= )
+	ffmpeg? ( media-video/ffmpeg:= )
+	gles2-only? ( media-libs/libglvnd )
+	!gles2-only? (
+		>=media-libs/glew-1.5.3:=
+		virtual/opengl:0=
+	)
+	rtmp? ( media-video/rtmpdump:= )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_GLES2=$(usex gles2-only)
+		-DENABLE_LIBAVCODEC=$(usex ffmpeg)
+		-DENABLE_RTMP=$(usex rtmp)
+
+		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+		-DENABLE_PROFILING=$(usex profile)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
+		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+		# TODO: install /etc/chromium file? block adobe-flash?
+		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use nsplugin; then
+		# copied from nsplugins.eclass, that's broken in EAPI 7
+		dodir /usr/$(get_libdir)/nsbrowser/plugins
+		dosym ../../lightspark/plugins/liblightsparkplugin.so \
+			/usr/$(get_libdir)/nsbrowser/plugins/liblightsparkplugin.so
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+
+	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+		elog "Having two plugins installed for the same MIME type may confuse"
+		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+		elog "USE flag for either gnash or lightspark. For details, see"
+		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}