app-admin/syslog-summary: Add ebuild that properly applies the patch

Signed-off-by: Vedant Sule <sulevedant@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/43796
Closes: https://github.com/gentoo/gentoo/pull/43796
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/app-admin/syslog-summary/syslog-summary-1.14-r6.ebuild b/app-admin/syslog-summary/syslog-summary-1.14-r6.ebuild
new file mode 100644
index 000000000000..3ab5ff935b5c
--- /dev/null
+++ b/app-admin/syslog-summary/syslog-summary-1.14-r6.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit python-single-r1
+
+DESCRIPTION="Summarizes the contents of a syslog log file"
+HOMEPAGE="https://github.com/dpaleino/syslog-summary"
+SRC_URI="https://github.com/dpaleino/syslog-summary/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 ~sparc x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-ignore-code.patch"
+	"${FILESDIR}/${P}-remove-file-magic.patch"
+	"${FILESDIR}/${P}-py3.patch"
+	"${FILESDIR}/${P}-fix-string-functions.patch"
+)
+
+src_prepare() {
+	python_fix_shebang -f syslog-summary
+
+	# Sadly, the makefile is useless for us.
+	rm Makefile || die
+
+	default
+}
+
+src_install() {
+	dobin syslog-summary
+	einstalldocs
+	doman syslog-summary.1
+
+	insinto /etc/syslog-summary
+	doins ignore.rules
+}