dev-cpp/catch: add 3.11.0

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-cpp/catch/catch-3.11.0.ebuild b/dev-cpp/catch/catch-3.11.0.ebuild
new file mode 100644
index 000000000000..310ba6525102
--- /dev/null
+++ b/dev-cpp/catch/catch-3.11.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/catchorg/Catch2.git"
+else
+	MY_P=${PN^}2-${PV}
+	SRC_URI="https://github.com/catchorg/Catch2/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Modern C++ header-only framework for unit-tests"
+HOMEPAGE="https://github.com/catchorg/Catch2"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCATCH_DEVELOPMENT_BUILD=ON
+		-DCATCH_ENABLE_WERROR=OFF
+		-DCATCH_BUILD_TESTING=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+
+	cmake_src_configure
+}