dev-cpp/xsimd: add 11.1.0, drop 11.0.0

Closes: https://bugs.gentoo.org/906359
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-cpp/xsimd/xsimd-11.1.0.ebuild b/dev-cpp/xsimd/xsimd-11.1.0.ebuild
new file mode 100644
index 000000000000..b1393fb6ae04
--- /dev/null
+++ b/dev-cpp/xsimd/xsimd-11.1.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="C++ wrappers for SIMD intrinsics"
+HOMEPAGE="https://github.com/xtensor-stack/xsimd"
+SRC_URI="https://github.com/xtensor-stack/${PN}/archive/refs/tags/${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		dev-python/breathe
+		dev-python/sphinx
+		dev-python/sphinx-rtd-theme
+	)
+	test? ( dev-cpp/doctest )"
+
+PATCHES=( "${FILESDIR}"/${P}-c++17.patch )
+
+src_prepare() {
+	sed -i \
+		-e '/fPIC/d' \
+		test/CMakeLists.txt \
+		|| die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && emake -C docs html
+}
+
+src_install() {
+	cmake_src_install
+	if use doc; then
+		dodoc -r docs/build/html
+	fi
+}