dev-cpp/catch add multilib support * This fix compile error on package with multilib support, such as spdlog, and require catch as dependency.

Bug: https://bugs.gentoo.org/962994
Signed-off-by: Gonçalo Negrier Duarte <gonegrier.duarte@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/43988
Signed-off-by: Sam James <sam@gentoo.org>

5 files changed, 138 insertions, 6 deletions

diff --git a/dev-cpp/catch/catch-1.12.2-r3.ebuild b/dev-cpp/catch/catch-1.12.2-r3.ebuild
new file mode 100644
index 000000000000..8ac51fa046ae
--- /dev/null
+++ b/dev-cpp/catch/catch-1.12.2-r3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/catchorg/Catch2.git"
+	EGIT_BRANCH="Catch1.x"
+else
+	MY_P=${PN^}-${PV}
+	SRC_URI="https://github.com/catchorg/Catch2/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+	S="${WORKDIR}/${PN^}2-${PV}"
+fi
+
+DESCRIPTION="Modern C++ header-only framework for unit-tests"
+HOMEPAGE="https://github.com/catchorg/Catch2"
+
+LICENSE="Boost-1.0"
+SLOT="1"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.12.2-glibc-2.34-sigstksz.patch
+)
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DNO_SELFTEST=$(usex !test)
+	)
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+	dodoc -r docs/.
+}
diff --git a/dev-cpp/catch/catch-1.9999.ebuild b/dev-cpp/catch/catch-1.9999.ebuild
index 479fa612486c..0c9994428a6d 100644
--- a/dev-cpp/catch/catch-1.9999.ebuild
+++ b/dev-cpp/catch/catch-1.9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit cmake
+inherit cmake-multilib
 
 if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
@@ -25,14 +25,14 @@ SLOT="1"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
-src_configure() {
+multilib_src_configure() {
 	local mycmakeargs=(
 		-DNO_SELFTEST=$(usex !test)
 	)
 	cmake_src_configure
 }
 
-src_install() {
+multilib_src_install() {
 	cmake_src_install
 	dodoc -r docs/.
 }
diff --git a/dev-cpp/catch/catch-2.13.10-r1.ebuild b/dev-cpp/catch/catch-2.13.10-r1.ebuild
new file mode 100644
index 000000000000..31ec3aa215f9
--- /dev/null
+++ b/dev-cpp/catch/catch-2.13.10-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/catchorg/Catch2.git"
+else
+	MY_P=${PN^}2-${PV}
+	SRC_URI="https://github.com/catchorg/Catch2/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Modern C++ header-only framework for unit-tests"
+HOMEPAGE="https://github.com/catchorg/Catch2"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCATCH_ENABLE_WERROR=OFF
+		-DBUILD_TESTING=$(usex test)
+	)
+	use test &&
+		mycmakeargs+=( -DPYTHON_EXECUTABLE="${PYTHON}" )
+
+	cmake_src_configure
+}
diff --git a/dev-cpp/catch/catch-3.8.1-r1.ebuild b/dev-cpp/catch/catch-3.8.1-r1.ebuild
new file mode 100644
index 000000000000..c661cf051f3b
--- /dev/null
+++ b/dev-cpp/catch/catch-3.8.1-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/catchorg/Catch2.git"
+else
+	MY_P=${PN^}2-${PV}
+	SRC_URI="https://github.com/catchorg/Catch2/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Modern C++ header-only framework for unit-tests"
+HOMEPAGE="https://github.com/catchorg/Catch2"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCATCH_DEVELOPMENT_BUILD=ON
+		-DCATCH_ENABLE_WERROR=OFF
+		-DCATCH_BUILD_TESTING=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+	)
+
+	cmake_src_configure
+}
diff --git a/dev-cpp/catch/catch-9999.ebuild b/dev-cpp/catch/catch-9999.ebuild
index 4c007ac4dc5f..ab1969170173 100644
--- a/dev-cpp/catch/catch-9999.ebuild
+++ b/dev-cpp/catch/catch-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 PYTHON_COMPAT=( python3_{10..13} )
 
-inherit cmake python-any-r1
+inherit cmake-multilib python-any-r1
 
 if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
@@ -32,7 +32,7 @@ pkg_setup() {
 	use test && python-any-r1_pkg_setup
 }
 
-src_configure() {
+multilib_src_configure() {
 	local mycmakeargs=(
 		-DCATCH_DEVELOPMENT_BUILD=ON
 		-DCATCH_ENABLE_WERROR=OFF