dev-db/spatialite: bump to 5.0.1

Seems to build with PROJ 8 as per upstream notes.

Bug: https://bugs.gentoo.org/685668
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-db/spatialite/spatialite-5.0.1.ebuild b/dev-db/spatialite/spatialite-5.0.1.ebuild
new file mode 100644
index 000000000000..57e64b658b39
--- /dev/null
+++ b/dev-db/spatialite/spatialite-5.0.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_PN="lib${PN}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A complete Spatial DBMS in a nutshell built upon sqlite"
+HOMEPAGE="https://www.gaia-gis.it/gaia-sins/"
+SRC_URI="https://www.gaia-gis.it/gaia-sins/${MY_PN}-sources/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="+geos iconv +proj test +xls +xml"
+# Further poking required
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-db/sqlite-3.7.5:3[extensions(+)]
+	sys-libs/zlib
+	geos? ( >=sci-libs/geos-3.4 )
+	proj? ( sci-libs/proj:= )
+	xls? ( dev-libs/freexl )
+	xml? ( dev-libs/libxml2 )
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="test? ( iconv )"
+
+src_configure() {
+	# 1) rttopo not yet packaged
+	# 2) gcp disabled for now to preserve MPL licence
+	econf \
+		--disable-rttopo \
+		--disable-gcp \
+		--disable-examples \
+		--disable-static \
+		--enable-epsg \
+		--enable-geocallbacks \
+		$(use_enable geos) \
+		$(use_enable geos geosadvanced) \
+		$(use_enable iconv) \
+		$(use_enable proj) \
+		$(use_enable xls freexl) \
+		$(use_enable xml libxml2)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}