dev-embedded/raspberrypi-utils: New package

This replaces media-libs/raspberrypi-userland(-bin), which is being last-rited.
The libraries are no longer maintained, but the utilities live on here.

Bug: https://bugs.gentoo.org/916953
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-embedded/raspberrypi-utils/raspberrypi-utils-0_p20240112.ebuild b/dev-embedded/raspberrypi-utils/raspberrypi-utils-0_p20240112.ebuild
new file mode 100644
index 000000000000..9628a77098f0
--- /dev/null
+++ b/dev-embedded/raspberrypi-utils/raspberrypi-utils-0_p20240112.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 cmake
+
+COMMIT="193e6e34b40807cbeedee2e4abc3ef5165e14ae2"
+
+DESCRIPTION="Raspberry Pi userspace utilities"
+HOMEPAGE="https://github.com/raspberrypi/utils"
+SRC_URI="https://github.com/raspberrypi/utils/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~arm ~arm64"
+
+RDEPEND="
+	!media-libs/raspberrypi-userland
+	!media-libs/raspberrypi-userland-bin
+"
+
+S="${WORKDIR}/utils-${COMMIT}"
+
+src_configure() {
+	local mycmakeargs=( -DBUILD_SHARED_LIBS=OFF )
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	local SRC
+	rm -r "${ED}"/usr/share/bash-completion/ || die
+	for SRC in */*-completion.bash; do
+		local DEST=${SRC%-completion.bash}
+		newbashcomp "${SRC}" "${DEST##*/}"
+	done
+}