dev-java/concurrentlinkedhashmap-lru: new package, add 1.4.2

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/28334/commits/86b0b47a127ab4f6fd78938557666e78bcf48a24
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/dev-java/concurrentlinkedhashmap-lru/concurrentlinkedhashmap-lru-1.4.2.ebuild b/dev-java/concurrentlinkedhashmap-lru/concurrentlinkedhashmap-lru-1.4.2.ebuild
new file mode 100644
index 000000000000..1cc5901e7454
--- /dev/null
+++ b/dev-java/concurrentlinkedhashmap-lru/concurrentlinkedhashmap-lru-1.4.2.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="com.googlecode.concurrentlinkedhashmap:concurrentlinkedhashmap-lru:${PV}"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A high performance version of java.util.LinkedHashMap for use as software cache"
+HOMEPAGE="https://github.com/ben-manes/concurrentlinkedhashmap"
+SRC_URI="https://github.com/ben-manes/concurrentlinkedhashmap/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN%lru}${P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+CP_DEPEND="dev-java/jsr305:0"
+
+RDEPEND=">=virtual/jre-1.8:*
+	${CP_DEPEND}"
+DEPEND=">=virtual/jdk-1.8:*
+	${CP_DEPEND}"
+
+JAVA_SRC_DIR="src/main/java"
+
+src_prepare() {
+	java-pkg-2_src_prepare
+	# https://github.com/ben-manes/concurrentlinkedhashmap/issues/46#issuecomment-160696203
+	rm src/main/java/com/googlecode/concurrentlinkedhashmap/ConcurrentHashMapV8.java || die
+	sed \
+		-e 's/ConcurrentHashMapV8/ConcurrentHashMap/' \
+		-i src/main/java/com/googlecode/concurrentlinkedhashmap/ConcurrentLinkedHashMap.java || die
+}