dev-lang/elixir: revbump due to changed RDEPEND

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-lang/elixir/elixir-1.14.5-r1.ebuild b/dev-lang/elixir/elixir-1.14.5-r1.ebuild
new file mode 100644
index 000000000000..9bba653e0598
--- /dev/null
+++ b/dev-lang/elixir/elixir-1.14.5-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Elixir programming language"
+HOMEPAGE="https://elixir-lang.org"
+SRC_URI="https://github.com/elixir-lang/elixir/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 ErlPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~riscv ~sparc ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+# https://hexdocs.pm/elixir/compatibility-and-deprecations.html#compatibility-between-elixir-and-erlang-otp
+DEPEND="
+	>=dev-lang/erlang-23:0=[ssl]
+	<dev-lang/erlang-26
+"
+# 'mix' tool collides with sci-biology/phylip, bug #537514
+RDEPEND="${DEPEND}
+	!!sci-biology/phylip
+"
+DEPEND+="
+	test? ( dev-vcs/git )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.9.1-disable-network-tests.patch
+	"${FILESDIR}"/${PN}-1.10.3-no-Q.patch
+	"${FILESDIR}"/${PN}-1.10.3-epmd-daemon.patch
+	"${FILESDIR}"/${PN}-1.14.1-make44-parallel-build.patch
+)
+
+src_install() {
+	emake DESTDIR="${D}" LIBDIR="$(get_libdir)" PREFIX="${EPREFIX}/usr" install
+	dodoc README.md CHANGELOG.md CODE_OF_CONDUCT.md
+}