dev-lang/python-exec: Bump to 2.2, needed for #568974

Bump to version 2.2 that makes it possible to symlink python-exec2-c
directly as wrapper. This is necessary to support wrapping
/usr/bin/python correctly on non-Linux systems where shebangs must only
reference real executables (rather than the Python script used so far).

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-lang/python-exec/python-exec-2.2.ebuild b/dev-lang/python-exec/python-exec-2.2.ebuild
new file mode 100644
index 000000000000..dbcb2ed726a8
--- /dev/null
+++ b/dev-lang/python-exec/python-exec-2.2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# Kids, don't do this at home!
+inherit python-utils-r1
+PYTHON_COMPAT=( "${_PYTHON_ALL_IMPLS[@]}" )
+
+# Inherited purely to have PYTHON_TARGET flags which will satisfy USE
+# dependencies and trigger necessary rebuilds.
+inherit python-r1
+
+DESCRIPTION="Python script wrapper"
+HOMEPAGE="https://bitbucket.org/mgorny/python-exec/"
+SRC_URI="https://www.bitbucket.org/mgorny/${PN}/downloads/${P}.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="!<dev-python/python-exec-10000
+	!<app-eselect/eselect-python-20151117"
+
+src_configure() {
+	local pyimpls=() i EPYTHON
+	for i in "${PYTHON_COMPAT[@]}"; do
+		python_export "${i}" EPYTHON
+		pyimpls+=( "${EPYTHON}" )
+	done
+
+	local myconf=(
+		--with-eprefix="${EPREFIX}"
+		--with-python-impls="${pyimpls[*]}"
+	)
+
+	econf "${myconf[@]}"
+}