dev-libs/chmlib: fix w/ clang 16

Closes: https://bugs.gentoo.org/871177
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-libs/chmlib/chmlib-0.40-r2.ebuild b/dev-libs/chmlib/chmlib-0.40-r2.ebuild
new file mode 100644
index 000000000000..cdbdd764997e
--- /dev/null
+++ b/dev-libs/chmlib/chmlib-0.40-r2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools out-of-source
+
+DESCRIPTION="Library for MS CHM (compressed html) file format"
+HOMEPAGE="http://www.jedrea.com/chmlib/"
+SRC_URI="http://www.jedrea.com/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv x86"
+IUSE="+examples static-libs"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.39-stdtypes.patch
+	"${FILESDIR}"/${P}-headers.patch
+	"${FILESDIR}"/${P}-clang16.patch
+)
+
+src_prepare() {
+	default
+	# Required for CONFIG_SHELL != bash (bug #668408)
+	eautoreconf
+}
+
+my_src_configure() {
+	local myeconfargs=(
+		$(use_enable examples)
+		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+my_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name '*.la' -delete || die
+}