dev-perl/Crypt-OpenSSL-RSA: Bump to version 0.310.0

- EAPI7
- Cleanup DESCRIPTION
- Always prune bad tests
- Parallel testing
- Ensure CFLAGS pass through to compiler via make

Upstream:
- Fix compat with OpenSSL 1.1.0
- Prefer hash mode NID_sha256 over NID_sha1 for sign
- Use Crypt::OpenSSL::Guess to find openssl stuff
- Use new interface for RSA_generate_key when possible
- Add fixes to work with LibreSSL better
- Remove default of SHA256 for RSA keys

Keywording:
- Due to new dependency dev-perl/Crypt-OpenSSL-Guess, the following
  keywords were dropped:
    alpha amd64-linux arm{,64} hppa ia64 m68k{,-mint} mips
    ppc{,-aix,-macos,64} s390 sparc{,-solaris,64-solaris}
    x64-{macos,solaris} x86-{linux,macos,solaris}

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-perl/Crypt-OpenSSL-RSA/Crypt-OpenSSL-RSA-0.310.0.ebuild b/dev-perl/Crypt-OpenSSL-RSA/Crypt-OpenSSL-RSA-0.310.0.ebuild
new file mode 100644
index 000000000000..87892490f35e
--- /dev/null
+++ b/dev-perl/Crypt-OpenSSL-RSA/Crypt-OpenSSL-RSA-0.310.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=TODDR
+DIST_VERSION=0.31
+inherit perl-module
+
+DESCRIPTION="RSA encoding and decoding using the OpenSSL libraries"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-perl/Crypt-OpenSSL-Bignum
+	dev-perl/Crypt-OpenSSL-Random
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:= )
+"
+DEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:= )
+"
+BDEPEND="${RDEPEND}
+	>=dev-perl/Crypt-OpenSSL-Guess-0.110.0
+	virtual/perl-ExtUtils-MakeMaker
+	test? (
+		virtual/perl-Test
+	)
+"
+PERL_RM_FILES=(
+	t/z_kwalitee.t
+	t/z_perl_minimum_version.t
+	t/z_meta.t
+	t/z_pod-coverage.t
+	t/z_pod.t
+)
+mydoc="rfc*.txt"
+
+src_compile() {
+	mymake=(
+		"OPTIMIZE=${CFLAGS}"
+	)
+	perl-module_src_compile
+}