dev-python/OutputCheck: fix Driver

remove deprecated open 'U' option

Closes: https://bugs.gentoo.org/891035
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/OutputCheck/OutputCheck-0.4.2-r1.ebuild b/dev-python/OutputCheck/OutputCheck-0.4.2-r1.ebuild
new file mode 100644
index 000000000000..fc9ebef88ec2
--- /dev/null
+++ b/dev-python/OutputCheck/OutputCheck-0.4.2-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool for checking the output of console programs inspired by LLVM's FileCheck"
+HOMEPAGE="https://github.com/stp/OutputCheck/"
+SRC_URI="https://github.com/stp/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-python/lit[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${P}-Driver.patch )
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Remove bad tests.
+	rm "${S}"/tests/invalid-regex-syntax.smt2 ||
+		die "failed to remove bad tests"
+
+	# Create RELEASE-VERSION file.
+	echo ${PV} > "${S}"/RELEASE-VERSION ||
+		die "failed to write RELEASE-VERSION"
+}
+
+python_test() {
+	lit --verbose "${S}"/tests || die "running test with ${EPYTHON} failed"
+}