dev-python/PyPDF2: add 2.1.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/PyPDF2/PyPDF2-2.1.0.ebuild b/dev-python/PyPDF2/PyPDF2-2.1.0.ebuild
new file mode 100644
index 000000000000..0af1c36fdea7
--- /dev/null
+++ b/dev-python/PyPDF2/PyPDF2-2.1.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=41b5cd4f774f8fbd8ac42d93b9962f0376352a15
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/PyPDF2/
+	https://github.com/py-pdf/PyPDF2/
+"
+SRC_URI="
+	https://github.com/py-pdf/PyPDF2/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Needs network access
+	tests/test_workflows.py::test_extract_textbench
+	"tests/test_page.py::test_page_operations[https://arxiv.org/pdf/2201.00029.pdf-None]"
+	tests/test_reader.py::test_iss925
+
+	# Broken test
+	tests/test_utils.py::test_deprecate_no_replacement
+)
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${P}"/sample-files/ || die
+	fi
+}