dev-python/elasticsearch: Bump to 9.0.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/dev-python/elasticsearch/Manifest b/dev-python/elasticsearch/Manifest
index 4004f007c023..efbecbfb9ae5 100644
--- a/dev-python/elasticsearch/Manifest
+++ b/dev-python/elasticsearch/Manifest
@@ -1 +1,2 @@
 DIST elasticsearch-py-9.0.1.gh.tar.gz 2189309 BLAKE2B 31f2e9541efdc90e85d40a462b45cd34ae4ffd8f44bb95af8c96cca44eb1b50cc0525b0d38ae3234a23ed986377ed3bd64325a46799d25c21214267cacf9279e SHA512 38ec30b85cc2d3ebef8dfde2bc7e07082240fcca6f98d9285a2d72876369f6a8233f973794c825f5564a99ca2c9a83f35c8eb954e123431c153309eb02f1f04c
+DIST elasticsearch-py-9.0.2.gh.tar.gz 2192777 BLAKE2B d7fc3c9fe94b954d0522be03335c7639e38a67fa30949f19a1004b368750ae87da5fd3ea87e048f6cc36c19a42883821ff3f986879ab6f61f4128add73a62c83 SHA512 b2473dae673051be4e6477947b9faddb11d1ac563a971c0b4eb14748ffdf3ab7eef89dbbdca27b486e631f575f7558341e46d22d551b1d20f100260d41c3b2c7
diff --git a/dev-python/elasticsearch/elasticsearch-9.0.2.ebuild b/dev-python/elasticsearch/elasticsearch-9.0.2.ebuild
new file mode 100644
index 000000000000..0c501f3ae811
--- /dev/null
+++ b/dev-python/elasticsearch/elasticsearch-9.0.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P="elasticsearch-py-${PV}"
+DESCRIPTION="Official Elasticsearch client library for Python"
+HOMEPAGE="
+	https://ela.st/es-python
+	https://github.com/elastic/elasticsearch-py/
+	https://pypi.org/project/elasticsearch/
+"
+SRC_URI="
+	https://github.com/elastic/elasticsearch-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+	<dev-python/elastic-transport-9[${PYTHON_USEDEP}]
+	>=dev-python/elastic-transport-8.15.1[${PYTHON_USEDEP}]
+	>=dev-python/orjson-3[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.4[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mapbox-vector-tile[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-api[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-sdk[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pyarrow[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+		dev-python/unasync[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/sphinx \
+	dev-python/sphinx-autodoc-typehints \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# REST api tests are a black hole for effort. It downloads the tests
+		# so its an ever moving target. It also requires effort to blacklist
+		# tests for apis which are license restricted.
+		"test_elasticsearch/test_server/test_rest_api_spec.py"
+		# Counting deprecation warnings from python is bound to fail even
+		# if all are fixed in this package. Not worth it.
+		"test_elasticsearch/test_client/test_deprecated_options.py"
+		# Running daemon for tests is finicky and upstream CI fails at it
+		# as well.
+		"test_elasticsearch/test_server/"
+		"test_elasticsearch/test_async/test_server/"
+		# require nltk
+		test_elasticsearch/test_dsl/test_integration/test_examples/_async/test_vectors.py
+		test_elasticsearch/test_dsl/test_integration/test_examples/_sync/test_vectors.py
+	)
+
+	local -x TEST_WITH_OTEL=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -p asyncio
+}