dev-python/elasticsearch: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 82 deletions

diff --git a/dev-python/elasticsearch/Manifest b/dev-python/elasticsearch/Manifest
index 0fe5baf9ceaf..4004f007c023 100644
--- a/dev-python/elasticsearch/Manifest
+++ b/dev-python/elasticsearch/Manifest
@@ -1,2 +1 @@
-DIST elasticsearch-py-8.18.1.gh.tar.gz 2035537 BLAKE2B 00df0311d76eff2fd101be6208ecef84d7f31c3ec3d8dd96f8674b6ac9f30a30153fd122fe510d36a40a6d11d5c44fe7d2cd043db667a4d0bb909da4e60b2bfc SHA512 c769999ae41be1715acc6ef99afc047e68be1c015e046afd0a9994e7167294c3aa839d81229577b9bfbd17611299ef3595f5b73fee27efb77af966575cee3e3f
 DIST elasticsearch-py-9.0.1.gh.tar.gz 2189309 BLAKE2B 31f2e9541efdc90e85d40a462b45cd34ae4ffd8f44bb95af8c96cca44eb1b50cc0525b0d38ae3234a23ed986377ed3bd64325a46799d25c21214267cacf9279e SHA512 38ec30b85cc2d3ebef8dfde2bc7e07082240fcca6f98d9285a2d72876369f6a8233f973794c825f5564a99ca2c9a83f35c8eb954e123431c153309eb02f1f04c
diff --git a/dev-python/elasticsearch/elasticsearch-8.18.1.ebuild b/dev-python/elasticsearch/elasticsearch-8.18.1.ebuild
deleted file mode 100644
index 3307a957e448..000000000000
--- a/dev-python/elasticsearch/elasticsearch-8.18.1.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{11..13} )
-
-inherit distutils-r1
-
-MY_P="elasticsearch-py-${PV}"
-DESCRIPTION="Official Elasticsearch client library for Python"
-HOMEPAGE="
-	https://ela.st/es-python
-	https://github.com/elastic/elasticsearch-py/
-	https://pypi.org/project/elasticsearch/
-"
-SRC_URI="
-	https://github.com/elastic/elasticsearch-py/archive/v${PV}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="Apache-2.0"
-SLOT="0/$(ver_cut 1)"
-KEYWORDS="amd64 arm64 ~x86"
-
-RDEPEND="
-	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
-	>=dev-python/aiohttp-3[${PYTHON_USEDEP}]
-	<dev-python/elastic-transport-9[${PYTHON_USEDEP}]
-	>=dev-python/elastic-transport-8.15.1[${PYTHON_USEDEP}]
-	>=dev-python/orjson-3[${PYTHON_USEDEP}]
-	dev-python/python-dateutil[${PYTHON_USEDEP}]
-	<dev-python/requests-3[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.4[${PYTHON_USEDEP}]
-	dev-python/typing-extensions[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		${RDEPEND}
-		dev-python/mapbox-vector-tile[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/opentelemetry-api[${PYTHON_USEDEP}]
-		dev-python/opentelemetry-sdk[${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pyarrow[${PYTHON_USEDEP}]
-		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
-		dev-python/python-dateutil[${PYTHON_USEDEP}]
-		>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
-		dev-python/unasync[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_sphinx docs/sphinx \
-	dev-python/sphinx-autodoc-typehints \
-	dev-python/sphinx-rtd-theme
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# REST api tests are a black hole for effort. It downloads the tests
-		# so its an ever moving target. It also requires effort to blacklist
-		# tests for apis which are license restricted.
-		"test_elasticsearch/test_server/test_rest_api_spec.py"
-		# Counting deprecation warnings from python is bound to fail even
-		# if all are fixed in this package. Not worth it.
-		"test_elasticsearch/test_client/test_deprecated_options.py"
-		# Running daemon for tests is finicky and upstream CI fails at it
-		# as well.
-		"test_elasticsearch/test_server/"
-		"test_elasticsearch/test_async/test_server/"
-		# require nltk
-		test_elasticsearch/test_dsl/test_integration/test_examples/_async/test_vectors.py
-		test_elasticsearch/test_dsl/test_integration/test_examples/_sync/test_vectors.py
-	)
-
-	local -x TEST_WITH_OTEL=1
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -o addopts= -p asyncio
-}