dev-python/errorhandler: bump to 2.0.1

Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/errorhandler/errorhandler-2.0.1.ebuild b/dev-python/errorhandler/errorhandler-2.0.1.ebuild
new file mode 100644
index 000000000000..042a4d7cb20f
--- /dev/null
+++ b/dev-python/errorhandler/errorhandler-2.0.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Logging framework handler"
+HOMEPAGE="https://pypi.org/project/errorhandler/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND=""
+DEPEND="
+	dev-python/pkginfo[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.0.1-no-intersphinx.patch
+)
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}