Merge updates from master

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/evdev/evdev-1.9.3.ebuild b/dev-python/evdev/evdev-1.9.3.ebuild
new file mode 100644
index 000000000000..7a06cfb86435
--- /dev/null
+++ b/dev-python/evdev/evdev-1.9.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1
+
+MY_P=python-evdev-${PV}
+DESCRIPTION="Python library for evdev bindings"
+HOMEPAGE="
+	https://python-evdev.readthedocs.io/
+	https://github.com/gvalkov/python-evdev/
+	https://pypi.org/project/evdev/
+"
+SRC_URI="
+	https://github.com/gvalkov/python-evdev/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# these tests rely on being able to open /dev/uinput
+	tests/test_uinput.py
+)
+
+python_configure_all() {
+	esetup.py build_ecodes \
+		--evdev-headers \
+		"${ESYSROOT}/usr/include/linux/input.h:${ESYSROOT}/usr/include/linux/input-event-codes.h:${ESYSROOT}:/usr/include/linux/uinput.h"
+}
+
+src_test() {
+	cd tests || die
+	distutils-r1_src_test
+}