dev-python/executing: Bump to 1.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/executing/executing-1.2.0.ebuild b/dev-python/executing/executing-1.2.0.ebuild
new file mode 100644
index 000000000000..eb688d352f1f
--- /dev/null
+++ b/dev-python/executing/executing-1.2.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Get information about what a Python frame is currently doing"
+HOMEPAGE="
+	https://github.com/alexmojaki/executing/
+	https://pypi.org/project/executing/
+"
+SRC_URI="
+	https://github.com/alexmojaki/executing/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/littleutils[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	# this test explodes when collected by pytest
+	"${EPYTHON}" tests/test_main.py || die "Tests failed with ${EPYTHON}"
+	epytest tests/test_pytest.py
+}
+
+pkg_postinst() {
+	optfeature "getting node's source code" dev-python/asttokens
+}