dev-python/flask-sqlalchemy: Bump to 2.4.1

Also bump EAPI to 7.

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Aaron W. Swenson <titanofold@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.4.1.ebuild b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.4.1.ebuild
new file mode 100644
index 000000000000..815d015a2f3d
--- /dev/null
+++ b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.4.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-SQLAlchemy"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="SQLAlchemy support for Flask applications"
+HOMEPAGE="https://pypi.org/project/Flask-SQLAlchemy/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.10[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Req'd for tests in py3
+DISTUTILS_IN_SOURCE_BUILD=1
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	pytest
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}