dev-python/gitdb: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 0 insertions, 54 deletions

diff --git a/dev-python/gitdb/gitdb-4.0.8.ebuild b/dev-python/gitdb/gitdb-4.0.8.ebuild
deleted file mode 100644
index 8c146410de5a..000000000000
--- a/dev-python/gitdb/gitdb-4.0.8.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-inherit distutils-r1
-
-DESCRIPTION="GitDB is a pure-Python git object database"
-HOMEPAGE="
-	https://github.com/gitpython-developers/gitdb
-	https://pypi.org/project/gitdb/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	>=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
-BDEPEND="
-	test? (
-		dev-vcs/git
-	)"
-
-distutils_enable_tests nose
-
-src_test() {
-	local i
-
-	mkdir "${T}"/repo || die
-	cd "${T}"/repo || die
-
-	for (( i = 0; i < 2500; ++i )); do
-		echo "${i}" > file"${i}" || die
-	done
-
-	git init || die
-	git config user.email "you@example.com" || die
-	git config user.name "Your Name" || die
-	git add -A || die
-	git commit -q -m ".." || die
-	git clone --bare "${T}"/repo "${T}"/repo.git || die
-	cd "${S}" || die
-
-	distutils-r1_src_test
-}
-
-python_test() {
-	#TRAVIS=1 disables performance tests which rely on the gitdb repo
-	local -x TRAVIS=1
-	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
-	nosetests -v || die "Tests fail with ${EPYTHON}"
-}