dev-python/ipython: Bump to 9.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 151 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index b9408867a507..60162439c8e3 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -3,3 +3,4 @@ DIST ipython-9.3.0.tar.gz 4426460 BLAKE2B d9d6ec38ab7ee2c4128869cd6fa0518c5df8ed
 DIST ipython-9.4.0.tar.gz 4385338 BLAKE2B 20bf17c945ab2c727aa340a500e2f452dadd440ff809e5aea2ebaa0bd146a6bf2103f2435549a0f4b898690e6aceb15850fc2ba92bb9b94d8e084b1f13cb17a1 SHA512 8e0bd35effa6b5d6d17b7903ae708f1db753717b2271c79b6662fc508e003a7b3b510604ed340e6e89a8c84abf7c3718f785eb39d0914b653c47adc999a1d2f4
 DIST ipython-9.5.0.tar.gz 4389137 BLAKE2B c9d0cccac9a7a0711425e74ecfde8bdb7789d8289d58d86dccaddd06c1012f4c5f94aedf444f8b6c313d04f7617c5d9adc191d7b25426d8f70622435207acbe5 SHA512 fddf470a03ed94dfe2e193dce0d7228bd1143706ce1cd189348d6778eb7d1650a1589e49bc050214337b5fd9c30e7f1d91f871bc0d4a0a04d1a227747a81a132
 DIST ipython-9.6.0.tar.gz 4396932 BLAKE2B 8e674c65f01dff76f4fc0bdd70bac64735cb188737c3b1c0b25fda407e2e7cd2231603306b49568bb74accba975c9dd63d08e7bda8ad8fae20be622ce3f6769e SHA512 32128f60bd5ef133f6f16636ec66bb407b8b8499aa40aa960076ad1ab78d150c5bea3a5508a4284302dd950e7a92ee045f9665c29914adfabd1eca7d8f50c470
+DIST ipython-9.7.0.tar.gz 4422115 BLAKE2B c79ed9d48daa647d3430f8f8a6cb7ea58be3bf9f283be0fb0a68bc530859db5f9cfd8419cef8c783ac7ae939fc111dd4a01841fa22f544135cda536100afbc6c SHA512 d611bd9c36a7497c4757895a074d89ef1bb0ac8def6c819bbe084879f6d44f506a5fa30bddff2249b5e0bb363206eb09b3e311037643ce8f17012513a2285e9f
diff --git a/dev-python/ipython/ipython-9.7.0.ebuild b/dev-python/ipython/ipython-9.7.0.ebuild
new file mode 100644
index 000000000000..cc5570b3121a
--- /dev/null
+++ b/dev-python/ipython/ipython-9.7.0.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples gui notebook nbconvert +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/decorator-4.3.2[${PYTHON_USEDEP}]
+	>=dev-python/ipython-pygments-lexers-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.18.1[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1.5[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.11.0[${PYTHON_USEDEP}]
+	>=dev-python/stack-data-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.11)
+"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.9[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.23[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	$(python_gen_cond_dep '
+		gui? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	' 'python*')
+	$(python_gen_cond_dep '
+		notebook? (
+			dev-python/notebook[${PYTHON_USEDEP}]
+			dev-python/ipywidgets[${PYTHON_USEDEP}]
+			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+		)
+	' 3.{11..13})
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=()
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# https://github.com/ipython/ipython/issues/14244
+				tests/test_display.py::TestAudioDataWithoutNumpy
+				# minor exception message mismatch
+				# https://github.com/ipython/ipython/issues/14976
+				tests/test_ultratb.py::ExceptionMessagePreferenceTest::test_jsondecodeerror_message
+			)
+			;;
+	esac
+
+	# nonfatal implied by virtx
+	nonfatal epytest || die "Tests failed on ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy?
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	# TODO2: figure out what TODO meant.
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}