dev-python/ipython: Bump to 9.0.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 149 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 1d913ec2d69a..f99714944ec5 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -3,3 +3,4 @@ DIST ipython-8.33.0.tar.gz 5508284 BLAKE2B feb808f159a6fe51e86030c0150fce6c42839
 DIST ipython-8.34.0.tar.gz 5508477 BLAKE2B 15c34a086ff4ec48ca97624e904cc4ebf55fe180ac3a222cafeab738c6b77676417e64b560fc73f3ae32cc22875fe4e3df13f5a5f170a8104fff00629aa0100e SHA512 1ff033b5d87ce21006d90469ac06f247cdf087ddd0b74e711b957d61428ffb64a42b459b879cfed60a312edcdd710e49cd76925bd0e3b8c89d18c8c79d8686d4
 DIST ipython-9.0.0.tar.gz 4364165 BLAKE2B 3835b9e0e6f1d6f64888a9e1d6499137d0316f871f2c330c73226338ffa064e1bff6163eddb5741d1b80a2e858bc08cfb64fb9f7ac59dd22c7d9cf990048ebb3 SHA512 9563e8c6a136e35fc87037662ea3b1d7caeff1fdff2c58ea446b7ac89aa777f900c4a3336a6a6a74d2f95d85ed080c1ea61fa4a9374560d1f0df8f73a2260a14
 DIST ipython-9.0.1.tar.gz 4365847 BLAKE2B 384bf9dfc5dc4a371acb6d52366d0dabada738bed26b6e37f8a4a19f26d885af97dbecfa6a7df638a8c35b9352afda7f6b785d927887a4707ff7bc6318ab009c SHA512 4c50e755516fc7077d2c25a4c53d3bc60af639d25854aed5e2f083975b0cc71d3873cff9d487ad99f3dc0b3d4ad6b4b9a751d99264a6ed6e32bc51d5cff3a792
+DIST ipython-9.0.2.tar.gz 4366102 BLAKE2B 68dbe8f0decbf7637522ef3e763562a31d678b350c58fd4eee3799409f5a67b85b289b1591f01e0e509765e8cffca60717b65f62e358e7af3b60b57b0185de4a SHA512 fb3e48a3f8ffc9e4a147cb8739b2458dd280f59798b24a001f3feb177ea372284b1aabd87ce57bc9647b578a2c81a476728efcf376ce3e735cc409c40dd32eed
diff --git a/dev-python/ipython/ipython-9.0.2.ebuild b/dev-python/ipython/ipython-9.0.2.ebuild
new file mode 100644
index 000000000000..28fe28b058c0
--- /dev/null
+++ b/dev-python/ipython/ipython-9.0.2.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~riscv"
+IUSE="examples notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/ipython-pygments-lexers[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/stack-data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.11)
+"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.9[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.23[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	$(python_gen_cond_dep '
+		qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	' 'python*')
+	$(python_gen_cond_dep '
+		notebook? (
+			dev-python/notebook[${PYTHON_USEDEP}]
+			dev-python/ipywidgets[${PYTHON_USEDEP}]
+			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+		)
+	' 3.{10..12})
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=()
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# https://github.com/ipython/ipython/issues/14244
+				tests/test_display.py::TestAudioDataWithoutNumpy
+			)
+			;;
+	esac
+
+	# nonfatal implied by virtx
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest -p asyncio --asyncio-mode=auto ||
+		die "Tests failed on ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}