dev-python/kafka-python: add 2.0.2, bump py3.10, fix test

- bump to python 3.10
- use optfeatures for all extra dependencies
- remove dependency on dev-python/unittest2

Closes: https://bugs.gentoo.org/723602
Signed-off-by: Zamarin Arthur <arthurzam@gmail.com>
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/kafka-python/kafka-python-2.0.2.ebuild b/dev-python/kafka-python/kafka-python-2.0.2.ebuild
new file mode 100644
index 0000000000000..fd96a67c40f0a
--- /dev/null
+++ b/dev-python/kafka-python/kafka-python-2.0.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Kafka protocol support in Python"
+HOMEPAGE="https://github.com/dpkp/kafka-python/ https://pypi.org/project/kafka-python/"
+SRC_URI="https://github.com/dpkp/kafka-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/xxhash[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/lz4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/snappy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# Needs the unpackaged crc32c module
+		test/record/test_util.py::test_crc32c[None]
+		# Needs kafka server running
+		test/test_consumer_integration.py::test_kafka_consumer_offsets_for_time_old
+	)
+	epytest ${deselect[@]/#/--deselect }
+}
+
+pkg_postinst() {
+	optfeature "LZ4 compression/decompression support" dev-python/lz4
+	optfeature "Snappy compression support" dev-python/snappy
+	optfeature "ZSTD compression/decompression support" dev-python/zstandard
+}