dev-python/libvirt-python: bump to 6.5.0

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/libvirt-python/libvirt-python-6.5.0.ebuild b/dev-python/libvirt-python/libvirt-python-6.5.0.ebuild
new file mode 100644
index 000000000000..d6867cec6ffc
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-6.5.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+DISTUTILS_USE_SETUPTOOLS=no
+
+MY_P="${P/_rc/-rc}"
+
+inherit distutils-r1
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://libvirt.org/git/libvirt-python.git"
+	RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+	SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="virtual/pkgconfig"
+BDEPEND="test? (
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/nose[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests setup.py
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}