dev-python/meson-python: Bump to 0.19.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-python/meson-python/Manifest b/dev-python/meson-python/Manifest
index d8fa20342a26..3dacdbe0c485 100644
--- a/dev-python/meson-python/Manifest
+++ b/dev-python/meson-python/Manifest
@@ -1 +1,2 @@
 DIST meson-python-0.18.0.gh.tar.gz 88056 BLAKE2B b8379a6cd37c3b4e89884e21ebb85ebed6a5d86575ea57388564659a0fcfab3d0f6b71bd49fc8014486118cf31af3a0a1c67a37afa1b9b93d634622a1bc40570 SHA512 f32f02851cdfc13f29550b297b3bce9038bdaf02381b15064e36442104e93624e090abeae23b9de97dfa971aa456716cae65dbe04784beee13b510db12de1000
+DIST meson-python-0.19.0.gh.tar.gz 93690 BLAKE2B 609aa2bbbfa63bd3b1a8954dd17d9c6182870b3567fc3d8954e5bb583b931e72ca1afc8b0dddb4ff48d798b88714b9c43810ea7e34d8c339884b243db3e3c403 SHA512 f3943b8b00eee962da5c734419d2793dca19bab962a2247369287b46f80203bc24eaa394ace93e988bf2f91808b6201d574907bd7070ab2e4c3f4f5df972e639
diff --git a/dev-python/meson-python/meson-python-0.19.0.ebuild b/dev-python/meson-python/meson-python-0.19.0.ebuild
new file mode 100644
index 000000000000..9d406f501ef4
--- /dev/null
+++ b/dev-python/meson-python/meson-python-0.19.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="Meson PEP 517 Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/meson-python/
+	https://github.com/mesonbuild/meson-python/
+"
+SRC_URI="
+	https://github.com/mesonbuild/meson-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+	>=dev-build/meson-0.63.0
+	!kernel_Darwin? ( dev-util/patchelf )
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		>=dev-python/cython-0.29.34
+		>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# Strip unnecessary Python-level dependency on meson, it is used
+	# as an external executable anyway.
+	sed -i -e '/meson >=/d' pyproject.toml || die
+}
+
+src_test() {
+	# required by tests/test_sdist.py::test_reproducible
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "The Test Suite" || die
+	git init -q || die
+	git add -A || die
+	git commit -m init -q || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	unset NINJA
+
+	local EPYTEST_DESELECT=()
+	if ! has_version "dev-build/meson[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_wheel.py::test_vendored_meson
+		)
+	fi
+
+	epytest
+}