dev-python/mkdocs-git-revision-date-localized-plugin: add version 0.10.0

Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/mkdocs-git-revision-date-localized-plugin/mkdocs-git-revision-date-localized-plugin-0.10.0.ebuild b/dev-python/mkdocs-git-revision-date-localized-plugin/mkdocs-git-revision-date-localized-plugin-0.10.0.ebuild
new file mode 100644
index 000000000000..4a3ee1f62f98
--- /dev/null
+++ b/dev-python/mkdocs-git-revision-date-localized-plugin/mkdocs-git-revision-date-localized-plugin-0.10.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="dev-python/mkdocs-material"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Display the localized date of the last git modification of a markdown file"
+HOMEPAGE="
+	https://github.com/timvink/mkdocs-git-revision-date-localized-plugin/
+	https://pypi.org/project/mkdocs-git-revision-date-localized-plugin/
+"
+SRC_URI="https://github.com/timvink/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/Babel-2.7.0[${PYTHON_USEDEP}]
+	dev-python/GitPython[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/click[${PYTHON_USEDEP}]
+		dev-python/mkdocs-material[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+	doc? ( dev-vcs/git )
+"
+
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# mkdocs-git-revision-date-localized-plugin's tests need git repo
+	if use test || use doc; then
+		git init -q || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -qm 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}