dev-python/mkdocstrings-python: Bump to 1.16.8

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/mkdocstrings-python/mkdocstrings-python-1.16.8.ebuild b/dev-python/mkdocstrings-python/mkdocstrings-python-1.16.8.ebuild
new file mode 100644
index 000000000000..5e65ff81b1c2
--- /dev/null
+++ b/dev-python/mkdocstrings-python/mkdocstrings-python-1.16.8.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python handler for dev-python/mkdocstrings"
+HOMEPAGE="
+	https://mkdocstrings.github.io/python/
+	https://github.com/mkdocstrings/python/
+	https://pypi.org/project/mkdocstrings-python/
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/griffe-1.6.2[${PYTHON_USEDEP}]
+	>=dev-python/mkdocstrings-0.28.3[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-autorefs-1.4[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-python/beautifulsoup4-4.12.3[${PYTHON_USEDEP}]
+		>=dev-python/inline-snapshot-0.18[${PYTHON_USEDEP}]
+		dev-python/mkdocs-material[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export PDM_BUILD_SCM_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# "None" meaning particular formatter not installed
+		"tests/test_rendering.py::test_format_code[None-print('Hello')]"
+		"tests/test_rendering.py::test_format_code[None-aaaaa(bbbbb, ccccc=1) + ddddd.eeeee[ffff] or {ggggg: hhhhh, iiiii: jjjjj}]"
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p inline_snapshot
+}