dev-python/netcdf4-python: Bump to 1.5.5

Closes: https://github.com/gentoo/gentoo/pull/18735
Closes: https://bugs.gentoo.org/612112
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/netcdf4-python/netcdf4-python-1.5.5.ebuild b/dev-python/netcdf4-python/netcdf4-python-1.5.5.ebuild
new file mode 100644
index 000000000000..1bcc154d3094
--- /dev/null
+++ b/dev-python/netcdf4-python/netcdf4-python-1.5.5.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=bdepend
+PYTHON_COMPAT=( python3_{6..9} )
+inherit distutils-r1 optfeature
+
+MY_PN="netCDF4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python/numpy interface to the netCDF C library"
+HOMEPAGE="https://unidata.github.io/netcdf4-python/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/cftime[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/hdf5
+	sci-libs/netcdf:=[hdf5]"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${P}-tests.patch )
+
+S="${WORKDIR}"/${MY_P}
+
+python_test() {
+	cd test || die
+	"${EPYTHON}" run_all.py || die
+}
+
+pkg_postinst() {
+	optfeature "HDF4 support" sci-libs/hdf sci-libs/netcdf[hdf]
+	optfeature "MPI parallel IO support" sci-libs/hdf5[mpi] sci-libs/netcdf[mpi]
+	optfeature "OPeNDAP support" net-misc/curl sci-libs/netcdf[dap]
+}