dev-python/openapi-spec-validator: Bump to 0.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/openapi-spec-validator/openapi-spec-validator-0.8.0.ebuild b/dev-python/openapi-spec-validator/openapi-spec-validator-0.8.0.ebuild
new file mode 100644
index 000000000000..025a1b5ed578
--- /dev/null
+++ b/dev-python/openapi-spec-validator/openapi-spec-validator-0.8.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYPI_VERIFY_REPO=https://github.com/python-openapi/openapi-spec-validator
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenAPI 2.0 (aka Swagger) and OpenAPI 3.0 spec validator"
+HOMEPAGE="
+	https://github.com/python-openapi/openapi-spec-validator/
+	https://pypi.org/project/openapi-spec-validator/
+"
+
+LICENSE="BSD"
+SLOT="0"
+if [[ ${PV} != *_beta* ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+RDEPEND="
+	>=dev-python/jsonschema-4.24.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-path-0.4.2[${PYTHON_USEDEP}]
+	>=dev-python/lazy-object-proxy-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/openapi-schema-validator-0.7.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Internet
+	tests/integration/test_shortcuts.py::TestPetstoreV2Example
+	tests/integration/test_shortcuts.py::TestApiV2WithExampe
+	tests/integration/test_shortcuts.py::TestPetstoreV2ExpandedExample
+	tests/integration/test_shortcuts.py::TestPetstoreExample
+	tests/integration/test_shortcuts.py::TestRemoteValidatev2SpecUrl
+	tests/integration/test_shortcuts.py::TestRemoteValidatev30SpecUrl
+	tests/integration/test_shortcuts.py::TestApiWithExample
+	tests/integration/test_shortcuts.py::TestPetstoreExpandedExample
+	tests/integration/test_validate.py::TestPetstoreExample
+	tests/integration/test_validate.py::TestApiWithExample
+	tests/integration/test_validate.py::TestPetstoreExpandedExample
+	tests/integration/validation/test_validators.py
+)
+
+src_prepare() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	# remove meaningless upper bounds
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}