dev-python/plotly: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 103 deletions

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index b3ee716ca7f56..3cc828a18fa66 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1,2 +1 @@
-DIST plotly.py-6.1.2.gh.tar.gz 10193925 BLAKE2B 21daa8e49c382bee311ebf4e976b233992d91d011b425e2294f7ce211c33a3c1113d23f4c5230ec6a8eb84e954ab035bc505f722ae3acfc858a0c9aff8740234 SHA512 bb614105fee5660bd1e530f3bfa361bd2d5306145d0cf8a9bac69f893f73d9754dba0b7edacd1f75d9734820a7e1f2f5ced9f0ac77c1265c621f89a37206a089
 DIST plotly.py-6.3.0.gh.tar.gz 10089966 BLAKE2B 1aed2cd325098fc06e39c0643e6cf6be330b60b50043ab625530fc51f6cf10d1302bc8335969ae115b445ca057b992b28c3a21e6634f7eca4e29fad7684e0084 SHA512 4923c78ca44388e17c36e00a4482c58d81deabe968a4b4d66da44d25abc8ee6ff10f28b11dfd18455abf8894478310e2872e6f10b358555c8a758958910dae98
diff --git a/dev-python/plotly/plotly-6.1.2.ebuild b/dev-python/plotly/plotly-6.1.2.ebuild
deleted file mode 100644
index 61823207ef8cb..0000000000000
--- a/dev-python/plotly/plotly-6.1.2.ebuild
+++ /dev/null
@@ -1,102 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{11..13} )
-DISTUTILS_USE_PEP517=setuptools
-
-inherit distutils-r1
-
-MY_P=plotly.py-${PV/_}
-DESCRIPTION="Browser-based graphing library for Python"
-HOMEPAGE="
-	https://plotly.com/python/
-	https://github.com/plotly/plotly.py/
-	https://pypi.org/project/plotly/
-"
-SRC_URI="
-	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV/_}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S="${WORKDIR}/${MY_P}"
-# The tests are not included in the PyPI tarball, to use the GitHub tarball
-# we have to skip npm, which means that the resulting install will
-# unfortunately lack the jupyterlab extension.
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-
-RDEPEND="
-	>=dev-python/narwhals-1.15.1[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/jupyter[${PYTHON_USEDEP}]
-		dev-python/jupyterlab[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/scikit-image[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/statsmodels[${PYTHON_USEDEP}]
-		dev-python/xarray[${PYTHON_USEDEP}]
-	)
-"
-
-# There are sphinx docs but we are missing a bunch of dependencies.
-# distutils_enable_sphinx ../../../doc/apidoc
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	distutils-r1_python_prepare_all
-
-	# Do not try to fetch stuff with npm
-	export SKIP_NPM=1
-}
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# requires polars
-		tests/test_optional/test_px
-
-		# requires kaleido
-		tests/test_optional/test_kaleido/test_kaleido.py
-	)
-
-	local EPYTEST_DESELECT=(
-		# requires polars
-		'tests/test_plotly_utils/validators/test_fig_deepcopy.py::test_deepcopy_dataframe[polars]'
-
-		# require anywidgets
-		'tests/test_io/test_to_from_json.py::test_from_json_output_type[FigureWidget-FigureWidget0]'
-		'tests/test_io/test_to_from_json.py::test_from_json_output_type[FigureWidget-FigureWidget1]'
-		'tests/test_io/test_to_from_json.py::test_read_json_from_filelike[FigureWidget-FigureWidget0]'
-		'tests/test_io/test_to_from_json.py::test_read_json_from_filelike[FigureWidget-FigureWidget1]'
-		'tests/test_io/test_to_from_json.py::test_read_json_from_pathlib[FigureWidget-FigureWidget0]'
-		'tests/test_io/test_to_from_json.py::test_read_json_from_pathlib[FigureWidget-FigureWidget1]'
-		'tests/test_io/test_to_from_json.py::test_read_json_from_file_string[FigureWidget-FigureWidget0]'
-		'tests/test_io/test_to_from_json.py::test_read_json_from_file_string[FigureWidget-FigureWidget1]'
-
-		# minor matplotlib incompatibility
-		plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
-		plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
-
-		# fails in non-isolated env
-		test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
-		test_init/test_lazy_imports.py::test_lazy_imports
-
-		# TODO
-		'tests/test_plotly_utils/validators/test_colorscale_validator.py::test_acceptance_named[Inferno_r]'
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest
-}