dev-python/pytest-httpserver: Bump to 1.0.9

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/pytest-httpserver/pytest-httpserver-1.0.9.ebuild b/dev-python/pytest-httpserver/pytest-httpserver-1.0.9.ebuild
new file mode 100644
index 000000000000..79f60d637991
--- /dev/null
+++ b/dev-python/pytest-httpserver/pytest-httpserver-1.0.9.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HTTP server for pytest to test HTTP clients"
+HOMEPAGE="
+	https://github.com/csernazs/pytest-httpserver/
+	https://pypi.org/project/pytest_httpserver/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# tests from building release artifacts
+		tests/test_release.py
+	)
+
+	epytest -p no:localserver
+}