dev-python/python-debian: bump to 0.1.37

Signed-off-by: Mike Gilbert <floppym@gentoo.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/dev-python/python-debian/python-debian-0.1.37.ebuild b/dev-python/python-debian/python-debian-0.1.37.ebuild
new file mode 100644
index 000000000000..0f352c156f2f
--- /dev/null
+++ b/dev-python/python-debian/python-debian-0.1.37.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python modules to work with Debian-related data formats"
+HOMEPAGE="https://packages.debian.org/sid/python-debian"
+SRC_URI="mirror://debian/pool/main/${P:0:1}/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+BDEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( app-arch/dpkg )
+"
+
+PATCHES=( "${FILESDIR}/0.1.36-disable-apt-pkg.patch" )
+
+python_compile_all() {
+	${EPYTHON} lib/debian/doc-debtags > README.debtags || die
+}
+
+python_test() {
+	${EPYTHON} -m unittest discover --verbose lib || die "Testing failed with ${EPYTHON}"
+}